R1 - Go Right

L1 - Go Left

Square - Select

Melee - Exit

    

EasyPrestigeSelector()

{

	self endon( "disconnect" );

	self endon( "death" );

	

	self.SelectorCurs = 1;

	

	self.Selector = [];

	

	self.Selector[ "BG" ] = createRectangle( "CENTER", "TOP", 0, 220, "white", 200, 200, (0.40, 0.40, 0.40), 1, 1 );

	self.Selector[ "SC" ] = createRectangle( "CENTER", "TOP", -50, 270, "white", 2, 12, (0, 0, 0), 1, 5 );

	self.Selector[ "Line" ] = createRectangle( "CENTER", "TOP", 0, 270, "white", 100, 2, (1, 1, 1), 1, 3 );

	self.Selector[ "Prestige" ] = createRectangle( "CENTER", "TOP", 0, 160, "rank_prestige" + self.SelectorCurs, 50, 50, (1, 1, 1), 1, 3 );

	self.Selector[ "Text" ] = createText( "objective", 1.3, self.SelectorCurs, "CENTER", "TOP", 0, 210, 10000, true, 1, (1, 1, 1) );

	wait .2;

	while(1)

	{

		self freezeControls( true );

		

		if( self attackButtonPressed())

		{

			self.Selector[ "SC" ].x += 10;

			self.SelectorCurs++;

			if( self.SelectorCurs > 11 )

				self.SelectorCurs = 1;

			self.Selector[ "Prestige" ] setShader( "rank_prestige" + self.SelectorCurs, 50, 50 );

			self.Selector[ "Text" ] setText( self.SelectorCurs );

			if( self.Selector[ "SC" ].x > 50 )

				self.Selector[ "SC" ].x = -50;

		}

		if( self AdsButtonPressed())

		{

			self.Selector[ "SC" ].x -= 10;

			if( self.Selector[ "SC" ].x < -50 )

				self.Selector[ "SC" ].x = 50;

			self.SelectorCurs--;

			if( self.SelectorCurs < 1 )

				self.SelectorCurs = 11;

			self.Selector[ "Prestige" ] setShader( "rank_prestige" + self.SelectorCurs, 50, 50 );

			self.Selector[ "Text" ] setText( self.SelectorCurs );

		}

		if( self UseButtonPressed() )

		{

			self setPlayerData( "prestige", self.SelectorCurs ); 

			self setPlayerData( "experience", 2516000 );

			self iPrintln( "^1Prestige " + self.SelectorCurs + " Set!" );

			wait 0.02;

			break;

		}

		if( self MeleeButtonPressed())

		{	

			break;

		}

		wait .05;

	}

	self freezeControls(false);

	self.Selector[ "BG" ] destroy();

	self.Selector[ "SC" ] destroy();

	self.Selector[ "Line" ] destroy();

	self.Selector[ "Prestige" ] destroy();

	self.Selector[ "Text" ] destroy();

}

    



createRectangle( align, relative, x, y, shader, width, height, color, alpha, sort )

{

	barElemBG = newClientHudElem( self );

	barElemBG.elemType = "bar";

	if ( !level.splitScreen )

	{

		barElemBG.x = -2;

		barElemBG.y = -2;

	}

	barElemBG.width = width;

	barElemBG.height = height;

	barElemBG.align = align;

	barElemBG.relative = relative;

	barElemBG.xOffset = 0;

	barElemBG.yOffset = 0;

	barElemBG.children = [];

	barElemBG.sort = sort;

	barElemBG.color = color;

	barElemBG.alpha = alpha;

	barElemBG setParent( level.uiParent );

	barElemBG setShader( shader, width , height );

	barElemBG.hidden = false;

	barElemBG setPoint(align,relative,x,y);

	return barElemBG;

}



createText( font, fontScale, text, point, relative, xOffset, yOffset, sort, hideWhenInMenu, alpha, color, glowAlpha, glowColor )

{

	textElem = createFontString(font, fontScale);

	textElem setText(text);

	textElem setPoint( point, relative, xOffset, yOffset );

	textElem.sort = sort;

	textElem.hideWhenInMenu = hideWhenInMenu;

	textElem.alpha = alpha;

	textElem.color = color;

	textElem.glowAlpha = glowAlpha;

	textElem.glowColor = glowColor;

	return textElem;

}

    

for ( i = 1; i < 12; i++)

		precacheShader( "rank_prestige" + i );